Gecko [ www.casapremiada.novaexata.com.br ]

Name	Size	Permission
capture_ssl_master_secrets.met...	664 B	-rw-r--r--
capture_ssl_master_secrets.stp	1.06 KB	-rwxr-xr-x
capture_ssl_master_secrets.txt	1.86 KB	-rw-r--r--
deviceseeks.meta	490 B	-rw-r--r--
deviceseeks.stp	884 B	-rwxr-xr-x
deviceseeks.txt	5.27 KB	-rw-r--r--
disktop.meta	381 B	-rw-r--r--
disktop.stp	1.75 KB	-rwxr-xr-x
eatmydata.meta	337 B	-rw-r--r--
eatmydata.stp	1.16 KB	-rwxr-xr-x
eatmydata.txt	304 B	-rw-r--r--
enospc.meta	332 B	-rw-r--r--
enospc.stp	2.18 KB	-rwxr-xr-x
inodewatch.meta	475 B	-rw-r--r--
inodewatch.stp	245 B	-rwxr-xr-x
inodewatch2.meta	504 B	-rw-r--r--
inodewatch2.stp	457 B	-rwxr-xr-x
io_submit.meta	508 B	-rw-r--r--
io_submit.stp	1.86 KB	-rwxr-xr-x
io_submit.tcl	140 B	-rw-r--r--
ioblktime.meta	769 B	-rw-r--r--
ioblktime.stp	788 B	-rwxr-xr-x
iodevstats.meta	738 B	-rw-r--r--
iodevstats.stp	1.12 KB	-rwxr-xr-x
iodevstats.txt	528 B	-rw-r--r--
iostat-scsi.meta	608 B	-rw-r--r--
iostat-scsi.stp	3.41 KB	-rwxr-xr-x
iostat-scsi.txt	481 B	-rw-r--r--
iostats.meta	671 B	-rw-r--r--
iostats.stp	1.12 KB	-rwxr-xr-x
iostats.txt	361 B	-rw-r--r--
iotime.meta	1 KB	-rw-r--r--
iotime.stp	2.83 KB	-rwxr-xr-x
iotop.meta	410 B	-rw-r--r--
iotop.stp	656 B	-rwxr-xr-x
mbrwatch.meta	559 B	-rw-r--r--
mbrwatch.stp	234 B	-rwxr-xr-x
mbrwatch.tcl	140 B	-rw-r--r--
mbrwatch.txt	788 B	-rw-r--r--
nfs_func_users.meta	665 B	-rw-r--r--
nfs_func_users.stp	341 B	-rwxr-xr-x
slowvfs.meta	426 B	-rw-r--r--
slowvfs.stp	281 B	-rwxr-xr-x
switchfile.meta	330 B	-rw-r--r--
switchfile.stp	231 B	-rw-r--r--
traceio.meta	403 B	-rw-r--r--
traceio.stp	1.35 KB	-rwxr-xr-x
traceio2.meta	400 B	-rw-r--r--
traceio2.stp	494 B	-rwxr-xr-x
ttyspy.meta	521 B	-rw-r--r--
ttyspy.stp	1.64 KB	-rwxr-xr-x
ttyspy.txt	455 B	-rw-r--r--

Code Editor : iostat-scsi.stp

#!/usr/bin/stap

global devices, reads, writes

/* data collection: SCSI disk */
%(kernel_v < "2.6.24" %?
probe module("sd_mod").function("sd_init_command") !,
      kernel.function("sd_init_command")
{
  device = kernel_string($SCpnt->request->rq_disk->disk_name)
  sector_size = $SCpnt->device->sector_size
  nr_sectors = $SCpnt->request->nr_sectors
  devices[device] = 1
%(kernel_v >= "2.6.19" %?
  if ($SCpnt->request->cmd_flags & 1)
%:
  if ($SCpnt->request->flags & 1)
%)
    writes[device] <<< nr_sectors * sector_size
  else
    reads[device] <<< nr_sectors * sector_size
}

%(kernel_v >= "2.6.31" %?
%{
#include <linux/blkdev.h>
%}

function get_nr_sectors:long(rq:long)
%{ /* pure */
  STAP_RETVALUE = blk_rq_sectors((const struct request *)(long)STAP_ARG_rq);
%}
%)

probe sd_prep_fn = module("sd_mod").function("sd_prep_fn") !,
		   kernel.function("sd_prep_fn")
{
  device = kernel_string($rq->rq_disk->disk_name)
  sector_size = @cast($q->queuedata, "scsi_device", "kernel<scsi/scsi_device.h>")->sector_size
%(kernel_v>="2.6.31" %?
  nr_sectors = get_nr_sectors($rq)
%:
  nr_sectors = $rq->nr_sectors
%)
  _cmd_flags = $rq->cmd_flags
}

probe sd_init_command = module("sd_mod").function("sd_init_command") !,
			kernel.function("sd_init_command")
{
  device = kernel_string(@choose_defined($cmd, $SCpnt)->request->rq_disk->disk_name)
  sector_size = @choose_defined($cmd, $SCpnt)->device->sector_size
  nr_sectors = get_nr_sectors(@choose_defined($cmd, $SCpnt)->request)
  _cmd_flags = @choose_defined($cmd, $SCpnt)->request->cmd_flags
}

probe sd_prep_fn !, sd_init_command
{
  devices[device] = 1
  if (_cmd_flags & 1)
    writes[device] <<< nr_sectors * sector_size
  else
    reads[device] <<< nr_sectors * sector_size
}

/* data collection: SCSI tape */
probe module("st").function("st_do_scsi").call !,
      kernel.function("st_do_scsi").call
{
  device = kernel_string($STp->disk->disk_name)
  devices[device] = 1
  if ($direction)
    writes[device] <<< $bytes
  else
    reads[device] <<< $bytes
}
/*
 * Handle inlined version of function separately, since on some kernels
 * (3.10.0-196.el7.ppc64) the variables aren't available (bad
 * debuginfo). We want to handle this separately from the '.call'
 * version, so that we'll know if the variable names change.
 */
probe module("st").function("st_do_scsi").inline !,
      kernel.function("st_do_scsi").inline ?
{
  if (@defined($STp) && @defined($direction) && @defined($bytes)) {
    device = kernel_string($STp->disk->disk_name)
    devices[device] = 1
    if ($direction)
      writes[device] <<< $bytes
    else
      reads[device] <<< $bytes
  }
}

/* reporting */
global blksize = 512
global hdrcount
probe timer.s($1)
{
  if ((hdrcount % 10) == 0)
    printf("%9s %9s %9s %9s %9s %9s\n",
           "Device:", "tps", "blk_read/s", "blk_wrtn/s", "blk_read", "blk_wrtn")
  hdrcount++

foreach (dev in devices) {
    rdcount = @count(reads[dev])
    wrcount = @count(writes[dev])
    tps = (rdcount + wrcount) * 100 / $1
    rdblkcount = rdcount ? @sum(reads[dev]) / blksize : 0
    wrblkcount =wrcount ? @sum(writes[dev]) / blksize : 0
    rdblkrate = rdblkcount * 100 / $1
    wrblkrate = wrblkcount * 100 / $1
    printf("%9s %6d.%02d %6d.%02d %6d.%02d %9d %9d\n",
           dev, tps / 100, tps % 100,
           rdblkrate / 100, rdblkrate % 100,
           wrblkrate / 100, wrblkrate % 100,
           rdblkcount, wrblkcount)
  }
  printf("\n")
  delete devices
  delete reads
  delete writes
}

${this.title}

Code Editor : iostat-scsi.stp